Programming & Security

Posted: 25 Oct 2009 10:31 AM PDT

You want to edit information on 25 records on the Form randomly. You will open the main data editing Form. Search for the record by entering the Key Value to find (say Employee Code or OrderID Value) in the Find (Ctrl+F) control and edit the record when found on the Form. This procedure is repeated for all 25 records for the first time because you don't have any other choice to find and edit the information.

But, the information you have changed is very critical and any mistakes in them may lead to serious issues. Mistakes can easily creep-in when you go through the finding and editing procedure in a hurry. It is important that you should have a second look at each record to verify and ensure the accuracy of changes.

Going through the same procedure to find all those 25 records again by displaying the Find control, keying in the Key Values and clicking on the Find button to reach the required record is not as enjoyable as it did for the first time.

But, if you can reach all those distant records one by one, in the same order of editing, without going through the above cumbersome procedure then it will be a great relief and can finish the work fast.

Why I said in the same order during editing because you are holding the source document of changes in the same order of your first visit to the records.

We will develop a trick with the Form's Bookmarks to make this kind of work easier for our Application Users.

FORM BOOKMARKS

When you open a Form attached to a Table, Query or SQL Statement each record on the Form is marked by MS-Access with a unique identifying tag known as Bookmark (a two Byte string Value). This is happening every time you open the Form with the above record sources. The Bookmarks are valid only on the current session of the Form and not stored in Tables.

We can read the Bookmark of any record from the Form's Bookmark Property, when the Record is Current on the Form, and store it in Variables in memory. Bookmarks saved this way can be used again to go back quickly to the same record we have visited earlier.

I have created a Function with the name myBookMarks() for this purpose and you can implement this method on any Form that has a Recordset attached to it by creating a Combo Box and a Command Button and four lines of Code in the VBA Code Module of the Form to run the Function.

You will definitely get a pat on your back from the User of your MS-Access Application for implementing this simple feature. So, let us start with our sample Project.

SAMPLE PROJECT

Open your VBA Editing Window (Alt+F11).

Create a new Standard Module (Insert - -> Module), Copy and Paste the following Code of myBookMarks() Function into the Module and Save it:



Option Compare Database
Option Explicit

Public Const ArrayRange As Integer = 25
Dim bookmarklist(1 To ArrayRange) As String, ArrayIndex As Integer

Public Function myBookMarks(ByVal ActionCode As Integer, ByVal cboBoxName As String, Optional ByVal RecordKeyValue) As String
'-----------------------------------------------------------------
'Author : a.p.r. pillai
'Date   : October-2009
'URL    : www.msaccesstips.com
'Remarks: All Rights Reserved by www.msaccesstips.com
'-----------------------------------------------------------------
'Action Code : 1 - Save Bookmark in Memory
'            : 2 - Retrieve Bookmark and make the record current
'            : 3 - Initialize Bookmark List and ComboBox contents
'-----------------------------------------------------------------
Dim ctrlCombo As ComboBox, actvForm As Form, bkmk As String
Dim j As Integer, msg As String, bkmkchk As Variant
Dim strRowSource As String, strRStmp As String, matchflag As Integer
Dim msgButton As Integer

On Error GoTo myBookMarks_Err

If ActionCode < 1 Or ActionCode > 3 Then
   msg = "Invalid Action Code : " & ActionCode & vbCr & vbCr
   msg = msg & "Valid Values : 1,2 or 3"
   MsgBox msg, , "myBookMarks()"
   Exit Function
End If

Set actvForm = Screen.ActiveForm
Set ctrlCombo = actvForm.Controls(cboBoxName)
Select Case ActionCode
    Case 1
        bkmk = actvForm.Bookmark
        'check for existence of same bookmark in Array
        matchflag = -1
        For j = 1 To ArrayIndex
           matchflag = StrComp(bkmk, bookmarklist(j), vbBinaryCompare)
           If matchflag = 0 Then
               Exit For
           End If
        Next
        If matchflag = 0 Then
           msg = "Bookmark of " & RecordKeyValue & vbCr & vbCr
           msg = msg & "Already Exists. "
           MsgBox msg, , "myBookMarks()"
           Exit Function
        End If
        'Save Bookmark in Array
        ArrayIndex = ArrayIndex + 1
        If ArrayIndex > ArrayRange Then
          ArrayIndex = ArrayRange
          MsgBox "Boookmark List Full. ", , "myBookMarks()"
          Exit Function
        End If
        bookmarklist(ArrayIndex) = bkmk
        
        GoSub FormatCombo
        
        ctrlCombo.RowSource = strRowSource
        ctrlCombo.Requery
    Case 2
        'Retrieve saved Bookmark and make the record current
        j = ctrlCombo.Value
        actvForm.Bookmark = bookmarklist(j)
    Case 3
        'Erase all Bookmarks from Array and
        'Delete the Combobox contents
        msg = "Erase Current Bookmark List...? "
        msgButton = vbYesNo + vbDefaultButton2 + vbQuestion
        If MsgBox(msg, msgButton, "myBookMarks()") = vbNo Then
            Exit Function
        End If
        For j = 1 To ArrayRange
           bookmarklist(j) = ""
        Next
        ctrlCombo.Value = Null
        ctrlCombo.RowSource = ""
        ArrayIndex = 0
End Select

myBookMarks_Exit:
Exit Function

FormatCombo:
'format current Bookmark serial number
'and OrderID to display in Combo Box
strRStmp = Chr$(34) & Format(ArrayIndex, "00") & Chr$(34) & ";"
strRStmp = strRStmp & Chr$(34) & RecordKeyValue & Chr$(34)

'get current combobox contents
strRowSource = ctrlCombo.RowSource

'Add the current Bookmark serial number
'and OrderID to the List in Combo Box
If Len(strRowSource) = 0 Then
     strRowSource = strRStmp
Else
     strRowSource = strRowSource & ";" & strRStmp
End If
Return

myBookMarks_Err:
MsgBox Err.Description, , "myBookMarks()"
Resume myBookMarks_Exit
End Function

Import the following Tables from C:\Program Files\Microsoft Office\Office11\Samples\Northwind.mdb sample Database:

Order Details

Products

NB:

Order Details

Click on the Order Details Table to select it.

Select Form from Insert Menu and select AutoForm : Tabular from the displayed list.

MS-Access creates a Tabular Form quickly. Save the Form with the name Order Details.

Open Order Details Form in Design View.

Expand the Form Header area and move the Field Headings down for enough space to create a Combo Box and a Command Button as shown on the sample design above.

Display the ToolBox (View - ->ToolBox), if it is not already visible.

If the Control Wizards Tool Button is already in selected state then click on it to de-select it.

Select the Combo Box Tool from the ToolBox and draw a Combo Box in the Header Section of the Form as shown on the design above.

While the Combo Box is still in selected state; select Properties from View menu to display the Property Sheet of the Combo Box.

Change the following Property Values as shown below:

Name = cboBMList

Row Source Type = Value List

Column Count = 2

Column Widths = .5";1"

Bound Column = 1

List Rows = 8

List Width = 1.5"

Change the Caption of the Child Label, attached to the Combo Box, to Bookmark List: .

Create a Command Button to the right side of the Combo Box.

Display the Property Sheet of the Command Button.

Change the following Property Values as shown Below:

Name = cmdReset

Caption = << Reset

Display the Code Module of the Form (View - -> Code).

Copy and Paste the following VBA Code into the Module; Save and Close the Form:



Option Compare Database

Private Sub Form_DblClick(Cancel As Integer)
    'Save Current Record's Bookmark in memory
    myBookMarks 1, "cboBMList", Me![OrderID]
End Sub

Private Sub cboBMList_Click()
    'Retrieve the bookmark using the
    'index number from the Combobox List
    'and make the respective record current
    myBookMarks 2, "cboBMList"
End Sub

Private Sub cmdReset_Click()
    'Initialize Bookmarks and Combobox contents
    myBookMarks 3, "cboBMList"
End Sub

Private Sub Form_Unload(Cancel As Integer)
    'Remove all Bookmarks from Memory
    myBookMarks 3, "cboBMList"
End Sub

Open the Order Details Form in Normal View.

Double-Click on one of the record-selectors at the left side of the Form.

Click on the Combo Box Drop-down control to check whether the OrderID value of the Record that you have double-clicked is added into the Combo Box List with a sequence number in the first Column or not.

Make few more double-click on different Record selectors up or down on the form as you like.

Check the Combo Box contents again to ensure that all these record references are added into the Combo Box with running serial numbers.

Click on the drop-down control of the Combo Box to display the list of Bookmarks and click on one of the item from the list.

OrderId

Find

OrderID

BookMarkList

myBookMarks()

Public Const ArrayRange As Integer = 25
Dim bookmarklist(1 To ArrayRange) As String, ArrayIndex As Integer

Scroll down the vertical scrollbar of the Form and double-click on the Record-Selectors of few more records from distant area of the Recordset.

Now, try to reach any of these Bookmarks we have added into the list by selecting them one by one from the Combo Box List.

If you want to erase all those Bookmarks from the BookmarkList Array in memory click on the << Reset Command Button. After this, you can create a fresh list of Bookmarks.

The OrderID Field Value added to the Combo Box along with the Index Number of the Bookmark Array can be used to cross check with the retrieved record value to ensure correctness.

Let us look the Sub-Routines we have copied into the Form Module and check what they are doing.

Private Sub Form_DblClick(Cancel As Integer)
myBookMarks 1, "cboBMList", Me![OrderID]
End Sub

When you double-click on the Record Selector of a record the above Sub-Routine calls the main Function myBookmarks() with the following parameters:

Action Code : 1 - indicates to fetch the Current Bookmark (a two byte string value consists of displayable/non-displayable characters) from the Active Form and save it in Memory in BookMarkList Array after incrementing the Array index number in Variable ArrayIndex. The Action Code is tested in the Select Case….End Select segment in the myBookMarks() Function. The Bookmark value itself is not displayed anywhere.

Combo Box Name : "cboBMList" – to display the Index Number of the BookmarkList Array in the Combo Box. The Name of the Control is enough to reference it on the Active Form.

Record Field Value : OrderID – to display the Record Field Value in the Combo Box along with the BookMarkList Array Index number. You can use any Field Value of your Table so far as it serves the purpose of checking the correctness of the record retrieved using the Bookmark.

The third parameter of myBookMarks() Function is defined as Optional and is omitted while calling the Functions to retrieve the Bookmark or to erase the Bookmarks List in the following three Sub-Routines respectively:

Private Sub cboBMList_Click()
myBookMarks 2, "cboBMList"
End Sub

Private Sub cmdReset_Click()
myBookMarks 3, "cboBMList"
End Sub

'Erases the Bookmarks when the Form is closed
Private Sub Form_Unload(Cancel As Integer)
'Remove all Bookmarks from Memory
myBookMarks 3, "cboBMList"
End Sub

Since, the main Function myBookMarks() references the Active Form you can implement this method on any Form without directly passing any Form Name to the Function.

NB:

Saving, retrieving and using Bookmarks for finding records is valid only for the current session of the Form.

Re-querying the Form's contents (not Refreshing) re-creates the Bookmarks for the Recordset on the form and earlier saved Bookmarks may not be valid after that. You must create fresh Bookmark List to use correctly.